#!/usr/bin/perl -w

$Version='0.1';

=head1 NAME

mkpic - interface for making pictures with mfpic

=head1 SYNOPSIS
 	
	mkpic [-pdf] [filename]

options:

       --pdf      pdf output instead of dvi
       --clean    remove all but input file and die
       --keep     keep unnecessary files after run
       --box      produce framed boxes
       --version  report version number and die
       --help     display help info and die

commands:

    begin    name xl yl xmin ymin xmax ymax xlabel ylabel
    xmark    [label1] x1 [label2] x2 ...
    Xmark    [label1] x1 [label2] x2 ...
    ymark    [label1] y1 [label2] y2 ...
    Ymark    [label1] y1 [label2] y2 ...
    xdrop    x y
    ydrop    x y
    xydrop   x y
    arrow    x1 y1 x2 y2 label
    label    YX x y label
    point    x1 y1 x2 y2 ...
    lines    x1 y1 x2 y2 ...
    curve    x1 y1 x2 y2 ...
    rect     x1 y1 x2 y2
    crect    x1 y1 x2 y2
    func     xmin xmax step expression-in-x
    grid     dx dy
    #         comment
    hatch    
    bhat    
    ehat    
    end    
    stop    

=head1 DESCRIPTION

B<mkpic> provides an easy interface for generating commands for making
small pictures with mfpic. To this end either an input file or a
C<__DATA__> section has to be created consisting of commands with space
separated parameters.  F<filename> is the name of the input file; if no
filename is given input is taken from the C<__DATA__> section. 

B<mkpic> produces two files: F<filename.mac>, a macro file which will contain
TeX commands for every picture, and F<filename.tex>, a TeX source file
containing nothing but the pictures produced. This TeX source file will be
compiled to a F<.dvi> file or, if the B<-pdf> option was present, to a F<.pdf> file.
If no F<filename> is given, F<mkpic.mac> will be used for the macro file, and
F<mkpic.tex> for the TeX source file.

The source is set up so that it is easy to add your own commands,
Currently the following commands are implemented:

=over 8

=item B<begin end>

Every picture begins with the B<begin> command and ends with the B<end>
command.  The B<begin> command defines a name for the picture and
defines a tex command with that name, prefixed with 'Fig'. The
resulting command> is written to a F<.mac> file. Thus the command

	begin aa ...

starts writing C<\def\Figaa{...> to the F<.mac> file, and the
picture can be reproduced in a TeX document by importing the F<.mac> file
and using the C<\Figaa> command. 

xl and yl are the lengths of the x- and y-axes. xlabel and ylabel are
the label that are placed at the ends of those axes. Use a space to
suppress labeling, or "-" to suppress drawing the axes at all.

=item B<xmark ymark Xmark Ymark>

These commands place one or more labels along the x- or y-axes, either
below (B<xmark> and B<ymark>) of above (B<Xmark> and B<Ymark>) the axis.

For the B<[xXyY]mark> commands a parameter containing any character
other than [-.0-9] is interpreted as the label to be placed and its
position is expected in the next parameter. If a parameter is just a
number, it is placed at that x-position.

=item B<xdrop ydrop xydrop>

These commands draw dotted arrows perpendicularly to the x-axis, the
y-axis and both axes, respectively, ending on the axes with the arrow
head.

=item B<arrow>

draws an arrow from I<(x1,y1)> to I<(x2,y2)> labeled on its tail with
I<label>

=item B<label>

draws a label at I<(x,y)>. I<YX> tells how it will be adjusted: for
Y=t,b,c I<(x,y)> will be, in the y-direction, on top, bottom or center
of the label respectively, for X=l,r,c it will be, in the x-direction,
left, right or center adjusted on I<(x,y)>. Thus 

	label tl 0 0 Hello

will draw the string Hello with its lower left corner at (0,0)

=item B<point>

draws points (dots) at I<(x1,y1)>, I<(x2,y2)> etcetera.

=item B<lines> 

draws line segsments from I<(x1,y1)> to I<(x2,y2)>, I<(x3,y3)> etcetera.

=item B<curve>

draws a bezier curve from I<(x1,y1)> to I<(x2,y2)>, I<(x3,y3)> etcetera.

=item B<rect>

draws a rectangle with diagonal points at I<(x1,y1)> and I<(x2,y2)>.

=item B<crect>

clears a rectangle with diagonal points at I<(x1,y1)> and I<(x2,y2)>.

=item B<func>

draws the function given by I<expression-in-x> between I<xmin> and
I<xmax>, stepping with I<step> units in the x-direction.

=item B<grid>

draw dotted grid lines at distances dx and dy in the x- and y directions

=item #

denotes a comment

=item B<hatch>

hatch the closed curve that follows.

=item B<bhat>

starts a path that will eventually be closed, and then hatched.

=item B<ehat>

ends a path started with B<bhat>, closes it and then hatches it.

=item B<anything else>

will be inserted as is in the macro file, and therefore should be a
valid I<mfpic> statement. You use this when you need such a statement
only once, or a few times and therefore see no need to define a proper
command for it.

=item  B<stop>

stops further reading of the input. Useful if you have many pictures,
but want to see only the first few for testing purposes.

=item Z<>

=back

=head1 BUGS

=over 4

=item 1

In the usual TeX distributions, too little memory is reserved for mf. You'll 
probably have to append the following line to your F<texmf.cnf>:

main_memory.mf = 800000

=item 2

Currently only up to 256 pictures can be generated. In the future this problem
will probably be solved by introducing more than one font and generating
tex-command names that have the font name in front.

=item 3

In the figures produced, the bounding boxes cannot be trusted. They should fit
the printed part of the figure, but they are unpredictable.

=back

=head1 CHANGES

The initial version (4 Jan 1999) had no version number.

=over 4

=item B<version 0.1> 

=over 4

=item *

B<mkpic> is now completely plain TeX based. The F<.sty> extension has been replaced with F<.mac>.

=item *

with the option B<-pdf> B<mkpic> now generates PDF output I<via> pdftex.

=item *

the B<-box> option generates a box around each figure

=item *

numbers generated with the mark commands now are set in mathmode

=item *

at the end of the run, unneeded files are now removed unless the B<-keep> option was given

=item *

the option B<-clean> removes all files related to the inputfile and then quits

=back

=back

=head1 AUTHOR

Wybo H. Dekker (wybo@servalys.nl)

=cut

use Getopt::Long;
GetOptions('pdf'     => \$pdf,     # pdf output instead of dvi
           'clean'   => \$clean,   # remove all but input file and don't run
           'keep'    => \$keep,    # keep unnecessary files after run
	   'box'     => \$box,     # produce framed boxes
	   'version' => \$version, # report version number and die
	   'help'    => \$help,    # display help info and die
          );

$help and die 'usage: mkpic [options] [file]

       options:
       --pdf      pdf output instead of dvi
       --clean    remove all but input file and die
       --keep     keep unnecessary files after run
       --box      produce framed boxes
       --version  report version number and die
       --help     display help info and die

       Without an input file the DATA-section is used
';      
$version and die "mkpic version $Version\n";	  

# find printer density
if (open(IN,`kpsewhich --format="web2c files" mktex.cnf`)) { 
  while (<IN>) { 
    /BDPI=(\d+)/ and $dpi=$1,last;
  }
} else {
  warn "could not find mktex.cnf; forcing 600dpi\n";
  $dpi=600;
}

$pdf=$pdf ? 'pdf' : '';
$tex=shift;
if ($tex) { open(IN,$tex) or die "Could not open $tex\n"; $input=*IN }
     else { $input=*DATA; $tex='mkpic' }

open_macrofile();
for (("mf","${dpi}gf","${dpi}pk","log")) { unlink "$tex.$_" }
$clean and do { 
  for (qw(log dvi pdf mac tex tfm)) { unlink "$tex.$_" }
  exit 0;
};

open(TEX,">$tex.tex");
$box=$box?'ruledhbox':'hbox';
print TEX "\\input $tex.mac\n".
          '\input supp-vis'."\n".
          '\def\Fig#1{\vbox{\underbar{#1}\endgraf'."\n".
	  "\\$box".'{\csname Fig#1\endcsname\hfill\endgraf}}}'."\n".
	  '\nopagenumbers\vsize=260mm'."\n";

%pos=('x'=>'tc',	# positions for [xyXY]marks
      'y'=>'cr',
      'X'=>'bc',
      'Y'=>'cl'
     );
%names=();
while (<$input>) {
  chomp;
  s/\s*#.*//;		# remove comment
  next unless $_;	# skip empty lines
  /^begin/ and do {
    (undef,$name,$xl,$yl,$xmin,$ymin,
     $xmax,$ymax,$xlabel,$ylabel)=split;
    warn "$name\n";
    $names{$name} and die "multiple occurrences of picture named $name\n";
    $names{$name}=1;
    
    $xlabel="" if $xlabel eq '-';
    $ylabel="" if $ylabel eq '-';
    $xscale=int(100*$xl/($xmax-$xmin)+.5);
    $yscale=int(100*$yl/($ymax-$ymin)+.5);
    $dx=sprintf("%.2f",100/$xscale);
    $dy=sprintf("%.2f",100/$yscale);
    $yx=$ymin>0 ? $ymin : 0; # y-position of the x-axis
    $xy=$xmin>0 ? $xmin : 0; # x-position of the y-axis
    $xlo=$xy-$dx;	# x-pos of right side of y-markers
    $ylo=$yx-$dy;	# y-pos of top side of x-markers
    $xhi=$xmax+3*$dx;	# x-pos of left side of x-labels
    $yhi=$ymax+3*$dy;	# y-pos of bottom side of y-labels
    print 
      "%\n%====$name====\n".
      "\\def\\Fig$name\{\\mftitle{$name}%\n".
      "\\def\\xlo{$xlo}\\def\\xhi{$xhi}%\n".
      "\\def\\ylo{$ylo}\\def\\yhi{$yhi}%\n".
      "\\def\\xy{$xy}\\def\\yx{$yx}%\n".
      "\\mfpic[$xscale][$yscale]{$xmin}{$xmax}{$ymin}{$ymax}%\n".
      "\\hatchwd{2}%\n".
      #"\\tlabel[tr]($xmin,$ylo){~}%\n".
      ($xlabel ? "\\tlabel[bc]($xy,$yhi){$ylabel}%\n" : '').
      ($ylabel ? "\\tlabel[cl]($xhi,$yx){$xlabel}%\n" : '');
    print TEX "\\Fig{$name}%\n";
  },next;
  /^arrow/ and do {
    (undef,$x1,$y1,$x2,$y2,$label)=split(/\s+/,$_,6);
    print "\\tlabel[bc]($x1,$y1){$label}%\n".
          "\\arrow\\lines{($x1,".($y1-$dy*3)."),($x2,$y2)}%\n";
  },next;
  /^[xyXY]mark/ and do {
    ($_,@z)=split;
    s/mark//;	# 'x', 'y', 'X' or 'Y'
    for ($i=0;$i<@z;$i++) {
      $label=$z[$i];
      if ($label =~ /^[-.\d]+$/) {
        $label="\$$label\$";
      } else {
        $i++;
      }
      $x=/x/i ? $z[$i] : /y/ ? $xlo : -$xlo;
      #   ^xmark?        ymark?       Ymark!
      $y=/y/i ? $z[$i] : /x/ ? $ylo : -$ylo;
      #   ^ymark?        xmark?       Xmark!
      print "\\tlabel[$pos{$_}]($x,$y)".
            "{\\strut $label}%\n";
    }
  },next;
  /^grid/ and do {
    (undef,$xdist,$ydist)=split;
	$topmaxy= (int ($ymax/$ydist) * $ydist);
	$lftmaxx= (int ($xmin/$xdist) * $xdist);
	$botmaxy= (int ($ymin/$ydist) * $ydist);
	$rtmaxx = (int ($xmax/$xdist) * $xdist);
	for ($t=$lftmaxx;$t<=$rtmaxx; $t+=$xdist) {
    print "\\dotted\\lines{($t,$botmaxy),($t,$topmaxy)}%\n";
  };
	for ($t=$botmaxy;$t<=$topmaxy;$t+=$ydist) {
    print "\\dotted\\lines{($lftmaxx,$t),($rtmaxx,$t)}%\n";
  };
  },next;
  /^drect/ and do {
    (undef,$xs,$ys,$xe,$ye)=split;
	print "\\lines{($xs,$ye),($xe,$ye)}%\n";
	print "\\dotted\\lines{($xs,$ys),($xs,$ye)}%\n";
	print "\\dotted\\lines{($xe,$ys),($xe,$ye)}%\n";
  },next;
  /^bar/ and do {
    my (undef,$xdev,$med,$ht)=split;
	$xs = $med - $xdev;
	$xe = $med + $xdev;
	$ys = 0;
	$ye = $ht;
	print "\\rect{($xs,$ys),($xe,$ye)}%\n";
  },next;
  /^(point|lines|curve|rect|crect)/ and do {    
                    # for example: crect 5 20 20 5
    s/^/\\/;        # \crect 5 20 20 5
    s/\s+/{(/;      # \crect{(5 20 20 5
    while(/ +/) {
      s/ +([-.\d]+) ?/,$1),\n(/;
    }               # \crect{(5,20),(20,5)
    s/,\n\($/}/;       # \crect{(5,20),(20,5)}
    s/crect/gclear\\rect/;
                    # \gclear\rect{(5,20),(20,5)}
    print "$_\n";
  },next;
  /^func/ and do {
    (undef,$x,$y,$d,$f)=split;
    print "\\function{$x,$y,$d}{$f}%\n";
  },next;
  /^hatch/ and do {
    print '\rhatch\draw\lclosed';
  },next;
  /^bhat/ and do {
    print '\rhatch\lclosed\connect',"\n";
  },next;
  /^ehat/ and do {
    print '\endconnect',"\n";
  },next;
  /^xdrop/ and do {
    (undef,$x,$y)=split;
    print "\\dotted\\arrow".
          "\\lines{($x,$y),($xy,$y)}%\n";
  },next;
  /^ydrop/ and do {
    (undef,$x,$y)=split;
    print "\\dotted\\arrow".
          "\\lines{($x,$y),($x,$yx)}%\n";
  },next;
  /^xydrop/ and do {
    (undef,$x,$y)=split;
    print "\\dashed\\arrow".
          "\\lines{($x,$y),($xy,$y)}%\n";
    print "\\dashed\\arrow".
          "\\lines{($x,$y),($x,$yx)}%\n";
  },next;
  /^labels/ and do {
    (undef,$m,$x,$y,@z)=split(/\s+/,$_);
    for ($i=0;$i<@z;$i++) {
      my $a = $x + $i;
      my $label = $z[$i];
      print "\\tlabel[$m]($a,$y){$label}%\n";
    }
  },next;
  /^label/ and do {
    (undef,$m,$x,$y,$label)=split(/\s+/,$_,5);
    $m=~/^[bct][lcr]$/ or die "illegal label in $_\n";
    print "\\tlabel[$m]($x,$y){$label}%\n";
  },next;
  /^end/ and do {
    # axes drawn last for easier rect clears:
    print "\\arrow[\\axisheadlen]\\lines".
          "{($xmin,$yx),($xmax,$yx)}%\n" if $xlabel;
    print "\\arrow[\\axisheadlen]\\lines".
          "{($xy,$ymin),($xy,$ymax)}%\n" if $ylabel;
    print "\\endmfpic}%\n";
  },next;
  /^stop/ and do { last };      # stop reading the input
  print "$_\n" if $_; # anything else printed literally
}
print TEX "\\closegraphsfile\\end\n";
close(TEX);
close(MAC);
sys("${pdf}tex --interaction batchmode $tex");
sys("mf '\\mode=localmode;' input $tex.mf");
sys("gftopk $tex.${dpi}gf $tex.${dpi}pk");
sys("${pdf}tex --interaction batchmode $tex");
unless ($keep) { 
  for (("log","mf","${dpi}gf","tex")) { unlink "$tex.$_" }
}

sub open_macrofile {
open(MAC,">$tex.mac"); select MAC;
print '% vim: syntax=tex
\input mfpic
\let\circle\undefinedcs
\opengraphsfile{'.$tex.'}
\mfpicunit.01mm
\parindent0pt\parskip2ex
';
}

sub sys {
  system(@_) and die "@_: $?\n";
}

__DATA__
begin b 20 20 0 0 20 20 - -
\pen{2pt}
lines 0 0 20 20 0 20 20 0 0 0
end

begin c 64 64 0 -6 4 5 $x$ $y$
xmark 2
Xmark 3
ymark -5 0 4
bhat
lines 0 0 0 4
func 0 3 .05 4-x*x
lines 3 -5 3 0
ehat
func 0 3.2 .05 4-x*x
xydrop 3 -5
arrow 3 4 1.7 1.1 $f(x)=4-x^2$
arrow 2 5 1 2 Area $O_1$
arrow 4 2 2.8 -2 Area $O_2$
end

begin d 64 64 0 3 12 8 $x$ $y$
xmark $a$ 2 $x_1$ 4 $x_2$ 8 $b$ 10
ydrop 2 4.414
ydrop 4 5
ydrop 8 5.828
ydrop 10 6.162
label cc 4 4 $f(x_1)$
label cc 8 4 $f(x_2)$
label cc 7 8 $f(x)$ increasing on $[a,b]$
label cc 7 7.5 $x_1<x_2\Rightarrow f(x_1)<F(x_2)$
func 1 11 .1 x**(.5)+3
end

begin e 64 64 0 0 10 10 $x$ $y$
curve 1 1 2 3 4 5.7 7 8.1 9 9
\shift{(-.05,.05)}
point 2 3 4 5.7 7 8.1
\shift{(-.05,.05)}
func 1.4 2.6 .1 1.65*x-.3
func 3.2 4.8 .1 1.025*x+1.6
func 6.1 7.9 .1 .62*x+3.76
label cl 9.5 9 $f(x)$
label tl 5 5 $f^\prime(x)>0$
label tl 5 4 $f^\prime(x)$ decreasing
end

begin f 64 64 -.85 -1.5 1.5 5 $x$ $y$
func -.6 1.5 .05 6*(x**4)-8*(x**3)+1
lines -.2 1 .2 1
label cr -.25 1 horizontal
arrow .5 2 0 1 inflection point
arrow .8 1 .65 0 inflection point
arrow 1 5 1.5 4.375 $f(x)=6x^4-8x^3+1$
Xmark 1
ymark \raise-8pt\hbox{0} 0 -1
xydrop 1 -1
end

begin g 64 64 -4 -4 4 4 - -
\dashed
lines -4 0 0 0 0 0 0 -4  # neg z and neg y
\dashed
lines 0 0 3 1.73         # neg x
\arrow
lines 0 0 0 4            # pos z
\arrow
lines 0 0 4 0            # pos y
\arrow
lines 0 0 -3 -1.73       # pos x
\dotted
lines -1 4 -1 0 -4 -1.73 # intersections y=-1 plane
\dotted
lines -1 -.577 -4 -.577  # intersection x=2 plane with xy-plane
% extra helplines
\dotted
lines -2 .423 -2 -.577 0 0 0 1 -2 .423
Ymark 3
% end of extras
\dotted
lines 0 3 -1 3 -4 1.27
\dashed\sclosed
curve -3 2.42 -1.5 2.711 -1 2.42 -2.5 2.134
label bc 0 \yhi $z$
label cl \xhi 0 $y$
label tr -3.1 -1.8 $x$
label cl -.85 -.577 2
label tc 0 5.5 $f(x,y)=x^2-4x+2y^2+4y+7$
xmark -1
Ymark 1
\shift{(-2,.42)}
\dashed
func 0 .5 .1 9*x*x
func -.5 0 .1 7*x*x
\dashed
func -1 0 .1 2*x*x
func 0 1 .1 2*x*x
label bl -3 -4 this one sticks out in left margin
label bl -3 -4.5 repair: comment out line 981 in mfpic.tex
label bl -3 -5 but then you see other figs stick out
label bl -3 -5.5 other repair: put this label  at x=-4
label bl -3 -6 or do: label cc -4 0 \~
end